home *** CD-ROM | disk | FTP | other *** search
/ Power Programmierung 2 / Power-Programmierung CD 2 (Tewi)(1994).iso / c / library / mslang / stepon / _temp302.sc_ / _temp302.sc
Encoding:
Text File  |  1994-04-30  |  14.1 KB  |  360 lines
  1. '                   ^^^^^^^^^^
  2. '              This program is configured in table part: Choose radio button Table
  3. '
  4. ' Hint:
  5. ' You're allowed to use this script or parts of changed or unchanged in your StepOne
  6. ' installation. 
  7. ' This script features professional installations for Windows and is full of hints and
  8. ' examples for your work with StepOne.
  9. ' If you change the table part (view: Table) of the script to your needs,
  10. ' you have a very good installation.
  11. ' One of the highlights of StepOne is the possibility to improve this installation script with 
  12. ' the powerful script language, so you have full control of the whole installation process.
  13. ' 
  14. ' If you start this program without making changes, a new path will be created.
  15. ' If you edit the tables of the Table part corresponding to your needs you get a full installation.
  16.  
  17. ' If you start this script within StepIt, the StepOne FastCodeBuilder, you have to set the path
  18. ' of the to be copied files with menue FASTCODE - SETTINGS - COMMANDLINE, i.e. 'a:'.
  19. ' If the path is followed with a space and -1, you're abled to get the information that
  20. ' StepOne was started within StepIt.
  21. ' ***************************************************************************************************
  22.  
  23. ' ***************************************************************************************************
  24. ' The command line (View: FastCode - Settings - Commandline)which StepIt.exe or Install.exe (FirstStep) 
  25. ' passes through is saved in a variable.
  26. Len "ln", "{_command}"
  27. If "{ln}" = "0"
  28.     Label "NoSourcePath"
  29.     PathBox "command", "Please choose the path of the to be installed files.", "Choose source path", "{_bootdrv}\", "", "", "0", "&OK"
  30. Else
  31.     Let "command", "{_command}"
  32. EndIf
  33. DirExist "res", "{command}"
  34. If "{res}" = "0"
  35.     Goto "NoSourcePath"
  36. EndIf
  37.  
  38. Split "sourcepath",    "{command}","32","1"
  39. Split "StepIt",        "{command}","32","2"
  40.  
  41. Let "prgname", "{prginfos[1;1]}"
  42. Let "mainprg", "{prginfos[2;1]}"
  43.  
  44. ' Look if program runs
  45. GoSub "CheckPrg","{mainprg}"
  46. ' Welcome the user and give hints of using the installation
  47. GoSub "Welcome"
  48. ' Checking VBX files if they are loaded or installed in the Windows directory
  49. GoSub "CheckLibraries"    
  50.  
  51. Label "copyloop"
  52. ' The user can choose the installation path
  53. GoSub "GetTargetPath",  "{prginfos[3;1]}"
  54. ' Create the choosen path
  55. GoSub "CreatePath"
  56. If "{path}" = "0"
  57.     ' If create operation fails or user choosed anything other
  58.     Goto "CopyLoop"
  59. EndIf
  60.  
  61. ' Install files
  62. GoSub "Copying"
  63. If "{space}" = "-1"
  64.     ' Copying failed because of unsufficient disk space.
  65.     ' User has to choose another drive.
  66.     Goto "CopyLoop"
  67. EndIf
  68.  
  69. ' Add icon(s) in Program Manager group
  70. GoSub "ProgMan"
  71.  
  72. ' Add Extension(s)in Registration Database
  73. GoSub "RegBase"
  74.  
  75. ' Edit program INI file(s)
  76. GoSub "PrgINIs"
  77. If "{prginfos[4;1]}" = "-1"
  78.     GoSub "ShareExe"
  79. EndIf
  80.  
  81. ' Inform user about end of installation.
  82. ' Name of program is passed through to give user the possibility to start program immediately.
  83. GoSub "PrgEnd"
  84. ' End of installation
  85. End
  86.  
  87. ' *************************************************************
  88. Sub "Welcome"
  89.     ' Show main window
  90.     Window "-1", "{prgname} Installation", "Welcome", "Welcome to installation of {prgname}. Installation program will lead you through all neccessary steps.{_nl}{_nl}Press Continue to start installation.{_nl}{_nl}Press keys Ctrl and C together to cancel installation.", "", "43;23;960;888", "9"
  91.      GetUserInput "&Continue"
  92. EndSub
  93.  
  94. ' ***************************************************************************************************
  95. Sub "GetTargetPath"
  96.     Parameter targetpath    
  97.     Window "-1", "", "Choose target path", "Please select the path where {prgname} should be installed to."
  98.     Label "GetTargetPath1"
  99.     ' If {ret} is a complete path, 'pathbox' uses only the part after the last backslash.
  100.     ' In example 'c:\windows\system' will be used from 'PathBox' paramter 'Additional Path' as 'system'.
  101.     ' PathBox parameter DefaultPath can contain a relative path, i.e.: 'c:\windows\..' get to 'c:\'.
  102.     PathBox "targetpath", "Please choose the path for {prgname}.", "", "{_windowsdir}\..", "{GetTargetPath:targetpath}", "", "0", "&OK;&Cancel"
  103.     If "{targetpath}" = ""
  104.         ' User has choosed 'Cancel'. AskEnd asks the user if he want to end the program.
  105.         'If user chooses 'Yes', AskEnd works like End.
  106.         AskEnd
  107.         Goto "GetTargetPath1"    
  108.     EndIf
  109. EndSub
  110. ' ***************************************************************************************************
  111. ' New VBX and DLL files can be installed if they aren't loaded.
  112. Sub "CheckLibraries"
  113.     ' If installation program is started within StepIt, check for libraries
  114.     ' isn't neccessary. StepIt uses 
  115.     ' cscombo.vbx, csdialog.vbx, csform.vbx, ss3d.vbx, ss3d2.vbx, qpro200.dll
  116.     ' Some installation programs would fail at this point.
  117.     ' If you don't use the libraries you should set the if selection as remark.
  118.     If "{StepIt}" <> "-1"
  119.         ' Gets number of elements
  120.         GetTableElementCount "number_vbx", "vbxtable"
  121.         For "i", "1", "{number_vbx}"
  122.             FileExist "wfound", "{_windowsdir}\{vbxtable[1;i]}"
  123.              If "{wfound}" = "-1"
  124.                 GoSub "CorrectVBX", "{i}"
  125.             EndIf
  126.         Next
  127.     EndIf
  128. EndSub
  129. ' *********************************************************************************************
  130. Sub "CorrectVBX"
  131.     Parameter "iVbx"
  132.     Label "Active"
  133.     'Copies a common used file    from windows to system directory to force version control
  134.     'It isn't checked if any of the common used files are installed anywhere on the users
  135.     'system. So, nevertheless version conflicts may occure. But this procedure
  136.     'fixed the common mistake to install vbx and dll in the windows directory.
  137.     IsTaskActive "res", "{vbxtable[1;i]}"
  138.     If "{res}" = "-1"
  139.         MsgBox "res", "'{vbxtable[1;i]}' is in use. Please exit the application which uses the file and try it again.{_NL}If you aren't sure which application uses the library please exit all applications except of the Program Manager and this program.", "", "&Retry;&Program End"
  140.         If "{res}" = "2"
  141.             GoSub CloseAll
  142.             End
  143.         Else
  144.             Goto "Active"
  145.         EndIf
  146.     Else
  147.         MsgBox "correct", "'{vbxtable[1;i]}' was found in your Windows directory. {_nl}Libraries like '{vbxtable[1;i]}' should be installed in System directory.{_nl}Should installation program '{vbxtable[1;i]}' correct the problem? To be sure that '{prgname}' runs correctly you should choose 'Correct'!", "", "&Correct;&Ignore"
  148.          If "{correct}" = "1"
  149.             Copy "{_windowsdir}\{vbxtable[1;i]}", "{_systemdir}\{vbxtable[1;i]}", "2" 
  150.             If "{_err}" = "0"
  151.                 Del "{_windowsdir}\{vbxtable[1;i]}"
  152.             Else
  153.                 OutBox "'{vbxtable[1;i]}' couldn't be moved to System directory. If '{prgname}' doesn't run you should repeat the installation."
  154.             EndIf
  155.         EndIf
  156.       EndIf
  157. EndSub
  158.  
  159. ' ***************************************************************************************************
  160. Sub "CheckPrg"
  161.     Parameter "p"
  162.     Label "CheckPrg2"
  163.     IsTaskActive "res","{CheckPrg:p}"
  164.     If "{res}" = "-1"
  165.         MsgBox "ret", "{CheckPrg:p} is active. To install a newer version you have to close it first, to be sure that version control works correct. Should installation program close {PrⁿfePrg:p} for you?", "", "&Task close;&Retry;&Program end"
  166.         If "{ret}" = "1"
  167.             TaskStop "{CheckPrg:p}"
  168.         EndIf
  169.         If "{ret}" = "3"
  170.             End
  171.         EndIf
  172.         Goto "CheckPrg2"
  173.     Else
  174.         Goto "CheckPrg1"
  175.     EndIf
  176. Label "CheckPrg1"
  177. EndSub
  178.  
  179. ' ***************************************************************************************************
  180. Sub "CreatePath"
  181.     DirExist "res", "{targetpath}"
  182.     If "{res}" = "0"
  183.         MsgBox "res", "'{targetpath}' doesn't exist.{_nl}Do you want to create the path?", "", "&Create;Change &selection;&Program end"
  184.         If "{res}" = "3"
  185.             End
  186.         EndIf
  187.         If "{res}" = "2"
  188.             Let "directory", "0"    
  189.             Goto "CreatePath1"    
  190.         EndIf
  191.         MkDir "{targetpath}"
  192.         If "{_err}" = "-1"
  193.             OutBox "During creation of path '{targetpath}' an error occurs. Please choose another path."
  194.             Let "directory", "0"        
  195.         Else
  196.             Let "directory", "-1"
  197.         EndIf
  198.     Else
  199.         Let "directory", "-1"
  200.     EndIf
  201. Label "CreatePath1"
  202. EndSub
  203.  
  204. ' ***************************************************************************************************
  205. Sub "Copying"
  206.     Window "-1", "", "Copying...", " "
  207.     SplitPathName "todrv", "{targetpath}", "5"
  208.     ' StepOne calcs the total of all file lengths and substracts the sum of
  209.     ' the file lengths which will be overwritten. The minimum isn't 0
  210.     ' indeed it is the length of the longest file, which should be installed
  211.     ' if the installation is on the same drive as temp drive.
  212.     CalcFileTable "targetbytes", "targettable", "{sourcepath}", "{targetpath}", "3"
  213.     CalcFileTable "systembytes", "systemtable", "{sourcepath}", "{_systemdir}", "3"
  214.     ' Checks if two given paths have the same drive name
  215.     If "{_systemdir}" := "{targetpath}"
  216.         Compute "tofreebytes","{tofreebytes}" + "{targetbytes}"
  217.     Else
  218.         GetDiskFree "systemfreebytes", "{_systemdir}"    
  219.         If "{systembytes}" > "{systemfreebytes}"
  220.             OutBox "On drive{_nl}'{todrv}'{_nl}isn't enough space free. {systembytes} bytes free space required.{_nl}Please free enough space on drive and retry installation."
  221.             End
  222.         EndIf
  223.     EndIf
  224.     GetDiskFree "tofreebytes", "{targetpath}"
  225.     If "{targetbytes}" > "{tofreebytes}"
  226.         OutBox "On drive{_nl}'{todrv}'{_nl}isn't enough space free. Please choose another drive."
  227.         Let "space", "-1"
  228.         Goto "Copying_end"
  229.     Else
  230.         Window "-1", "", "Copying...", "Please be patient..."
  231.         GetTableLineCount "number_copy", "targettable"
  232.         If "{number_copy}" > "0"
  233.             CopyFileTable "targettable", "{sourcepath}", "{targetpath}", "1", "0"
  234.             If "{_err}" = "-1"
  235.                 MsgBox "res", "During copying occurs errors. Do you want to continue installation nevertheless?", "", "&OK;&Program end"
  236.                 If "{res}" = "2"
  237.                     End
  238.                 EndIf
  239.             EndIf
  240.         EndIf
  241.         If "{StepIt}" <> "-1"
  242.             GetTableLineCount "number_copy", "systemtable"
  243.             If "{number_copy}" > "0"
  244.                 Window "-1", "", "Copying system files..."
  245.                 CopyFileTable "systemtable", "{sourcepath}", "{_systemdir}", "1", "0"
  246.                 'Make sure, dialog will be closed
  247.                 CopyFileTable
  248.                 If "{_err}" = "-1"
  249.                     MsgBox "res", "During copying occurs errors. Do you want to continue installation nevertheless?", "", "&OK;&Program end"
  250.                     If "{res}" = "2"
  251.                         End
  252.                     EndIf
  253.                 EndIf
  254.             EndIf
  255.         EndIf
  256.         Let "space", "0"    
  257.     EndIf
  258.     Label "copying_end"
  259. EndSub
  260.  
  261. ' ***************************************************************************************************
  262. Sub "ProgMan"
  263.     ' Get number of elements
  264.     GetTableLineCount "number_prg", "prgmantable"
  265.     If "{number_prg}" > "0"
  266.         Window "-1", "", "Installing icons...", "Please be patient..."
  267.         Let "i", "1"
  268.         Let "tmp",""
  269.         Label "ProgMan1"    
  270.         If "{tmp}" <>  "{prgmantable[i;1]}"
  271.             Let "tmp", "{prgmantable[i;1]}"
  272.             DDEExecute "ProgMan", "ProgMan", "", "[creategroup({prgmantable[i;1]})]"
  273.             If "{_err}" = "-1"
  274.                 OutBox "Group '{prgmantable[i;1]}' couldn't be created in Program Manager."
  275.             EndIf
  276.         EndIf
  277.         GoSub "icon","{prgmantable[i;1]}","{targetpath}\{prgmantable[i;2]}","{prgmantable[i;3]}"
  278.         Compute "i", "{i}" + "1"
  279.         If "{i}" <= "{number_prg}"
  280.             Goto "ProgMan1"
  281.         EndIf
  282.     EndIf
  283. EndSub
  284.  
  285. ' ***************************************************************************************************
  286. Sub "Icon"
  287. Parameter "group","name","title"
  288.     ' Sets the group window so that 'replaceitem' can find the group window
  289.     DDEExecute "ProgMan", "ProgMan", "", "[showgroup({icon:group},1)]"
  290.     DDEExecute "ProgMan", "ProgMan", "", "[showgroup({icon:group},2)]"
  291.     ' Deletes icon and saves position...
  292.     DDEExecute "ProgMan", "ProgMan", "", "[replaceitem({icon:title})]"
  293.     ' ... Additem can use it
  294.     DDEExecute "ProgMan", "ProgMan", "", "[additem({icon:name},{icon:title},,)]"
  295.     If "{_err}" = "-1"
  296.         OutBox "'{prgname}' icon couldn't be installed in Program Manager."
  297.     EndIf
  298.     ' Brings group window on top, so user can find it immediately.
  299.     DDEExecute "ProgMan", "ProgMan", "", "[showgroup({icon:group},1)]"
  300. EndSub
  301. ' ***************************************************************************************************
  302. Sub "RegBase"
  303.     ' Gets number of elements
  304.     GetTableLineCount "number_reg", "regbasetable"
  305.     If "{number_reg}" > "0"
  306.         Let "i", "1"
  307.         Label "RegBase1"    
  308.         RegBaseWrite "{regbasetable[i;2]}", "{regbasetable[i;3]}"
  309.         RegBaseWrite "{regbasetable[i;3]}", "{regbasetable[i;4]}"
  310.         RegBaseWrite "{regbasetable[i;3]}\shell\open\command", "{targetpath}\{regbasetable[i;5]}"
  311.         If "{regbasetable[i;1]}" <> "CMD"
  312.             RegBaseWrite "{regbasetable[i;3]}\shell\open\ddeexec", "{regbasetable[i;6]}"
  313.             RegBaseWrite "{regbasetable[i;3]}\shell\open\ddeexec\application", "{regbasetable[i;7]}"
  314.             RegBaseWrite "{regbasetable[i;3]}\shell\open\ddeexec\topic", "{regbasetable[i;8]}"
  315.         EndIf
  316.         Compute "i", "{i}" + "1"
  317.         If "{i}" <= "{number_reg}"
  318.             Goto "RegBase1"
  319.         EndIf
  320.     EndIf    
  321. EndSub
  322.  
  323. ' ***************************************************************************************************
  324. Sub "PrgINIs"
  325.     ' Gets number of elements
  326.     GetTableLineCount "number_ini", "initable"
  327.     If "{number_ini}" > "0"
  328.         Let "i","1"
  329.         Label "PrgINIs1"
  330.         INIWrite "{initable[i;1]}","{initable[i;2]}","{initable[i;3]}","{initable[i;4]}"
  331.         Compute "i", "{i}" + "1"
  332.         If "{i}" <= "{number_ini}"
  333.             Goto "PrgINIs1"
  334.         EndIf
  335.     EndIf
  336. EndSub
  337.  
  338. ' ***************************************************************************************************
  339. Sub "ShareExe"
  340.     If "{_locking}" = "0"
  341.         MsgBox "addlocking", "'{prgname}' needs a network or SHARE for his database. Installation program can install SHARE in your AUTOEXEC.BAT and restarts your system after end of installation to let the changes effect. Do you want to add SHARE? To make the changes on yourself choose 'Not install'.", "SHARE.EXE", "&Install;&Not install"
  342.         If "{addlocking}" = "1"
  343.             AddShareExe
  344.         EndIf    
  345.     EndIf
  346. EndSub
  347.  
  348. Sub "PrgEnd"
  349.     Window "-1", "", "Ready!", "It's completed. Installation of '{prgname}' is finished."
  350.     GetUserInput "&OK"
  351.     If "{addlocking}" = "1"
  352.         MsgBox "reboot", "Installation program has add SHARE.EXE to your AUTOEXEC.BAT. To let the changes effect you've to restart your system. Should installation program makes a restart?", "Warmstart", "&Restart;&No Restart"
  353.         If "{reboot}" = "1"
  354.             ReBoot "3"
  355.         Else
  356.             OutBox "Before start of {prgname} you've to restart your system."
  357.         EndIf
  358.     EndIf
  359. EndSub
  360.